home *** CD-ROM | disk | FTP | other *** search
/ The World of Computer Software / The World of Computer Software.iso / sa-book.zip / dumdum < prev    next >
Text File  |  1989-09-27  |  5KB  |  209 lines
  1. #!/bin/csh -f 
  2. # 
  3. # dumdum: script to do incremental dumps 
  4. #
  5.  
  6. onintr quit
  7. umask 7
  8.  
  9. # filesystems to be dumped on level 0 and 1
  10. set LOLEV =  "root usr net"
  11.  
  12. # filesystems to be dumped at every level
  13. set ALWAYS = "usr net"
  14.  
  15. # dump program to use 
  16. set DUMP = "/etc/dump"
  17.  
  18. # restore program to use
  19. set RESTORE = "/etc/restore"
  20.  
  21. # density of the tape
  22. set DEN = "1600"
  23.  
  24. # device to dump to
  25. set DUMPDEV = "/dev/mt0"
  26.  
  27. #directory where all dump information is stored
  28. set DUMPDIR = "/usr/local/adm/dumpdir"
  29. cd ${DUMPDIR}
  30.  
  31. #set up temporary file names
  32. set FLAGDIR = "${DUMPDIR}/flagdir"
  33. if (!(-d $FLAGDIR )) mkdir $FLAGDIR 
  34. set FLAGFILE = "${FLAGDIR}/dumpit"
  35. set FNAME = "tmp"
  36. set TEMPFILE = "${FLAGDIR}/${FNAME}$$"
  37.  
  38. # get the sequence information from the WHICHDUMP file
  39. set which = `cat ${DUMPDIR}/WHICHDUMP`
  40. set DATEFILE = "${DUMPDIR}/DUMPDATES"
  41. @ lessone = ${#which} - 1
  42. set nonomatch
  43.  
  44. start:
  45.  
  46. #if the last dump did not finish, restart it
  47. set junk = (`ls ${FLAGDIR}`)
  48. set isnotdone = (${junk})
  49. if (${#isnotdone} >= 1) then
  50.     echo "THIS IS THE CONTINUATION OF AN ABORTED DUMP"
  51.     echo "Continuing with a level ${which[${which[${#which}]}]} dump."
  52.     echo " "
  53.     echo -n "Is this correct? "
  54.     set junk = $<
  55.     while ((${junk} != "yes") && (${junk} != "no") &&  \
  56.         (${junk} != "y") && (${junk} != "n"))
  57.         echo -n "Please answer yes or no: "
  58.         set junk = $<
  59.     end
  60.     if ((${junk} == "n") || (${junk} == "no")) then
  61.         rm -f ${FLAGDIR}/*
  62.         goto start
  63.     endif
  64.     set restart
  65.     goto getlevel
  66. else
  67.  
  68. # increment the position counter (last element of array)
  69.     @ which[$#which]++
  70.  
  71. # if the position counter points to its own position in the array, recycle
  72. # back to the beginning of the array
  73.     if (${which[${#which}]} == ${#which}) set which[${#which}] = 1
  74. recover:
  75.     echo ""
  76.     echo -n "My records"
  77.     if (${?limit}) echo -n " now"
  78.     echo -n " indicate that this should be a "
  79.     echo " level ${which[${which[${#which}]}]} dump."
  80.     echo -n "Is this correct? "
  81.     set junk = $<
  82.     while ((${junk} != "yes") && (${junk} != "no") &&  \
  83.           (${junk} != "y") && (${junk} != "n"))
  84.         echo -n "Please answer yes or no: "
  85.         set junk = $<
  86.     end
  87.     if ((${junk} == "yes") || (${junk} == "y")) then
  88.         echo $which > ${DUMPDIR}/WHICHDUMP
  89.  
  90. # set the level - lolevel contains the number without sublevel information
  91. getlevel:
  92.         set level = ${which[${which[${#which}]}]}
  93.         set lolevel = `echo $level | tr -d "a-z"`
  94.     else
  95. #
  96. # list the dump sequence and corresponding numbers
  97. #
  98.         echo ""
  99.  
  100.         @ limit = $#which /  5 
  101.         set counter = 1
  102.         while ($counter <= $limit) 
  103.             set temp = $counter;
  104.             set i = 1
  105.                 while ($i <= 5) 
  106.                     echo -n "${temp}==$which[$temp]"
  107.                     if ($temp == $which[$#which]) then
  108.                         echo -n "*"
  109.                     endif
  110.                     echo -n "    "
  111.                     @ temp += 9;
  112.                     @ i++
  113.                 end
  114.                 echo ""
  115.                 @ counter++;
  116.         end
  117.  
  118.         echo "* marks the dumps I thought we were supposed to do."
  119.         echo ""
  120.         echo -n "What is the number of the correct dump? "
  121.  
  122.  
  123. # get the correct dump number
  124.         set junk = $<
  125.         while ((${junk} < "1") || (${junk} >= "${#which}"))
  126.             echo "Please choose a number between 1 and ${lessone}\!"
  127.             echo -n "What is the number of the correct dump? "
  128.             set junk = $<
  129.         end
  130.         set which[${#which}] = ${junk}
  131.         goto recover
  132.     endif
  133. endif
  134.  
  135. echo ""
  136.  
  137. if ((${lolevel} == "0") || (${lolevel} == "1")) then
  138.     set fs = "${LOLEV}"
  139. else
  140.     set fs = "${ALWAYS}"
  141. endif
  142.  
  143. echo "Doing these file systems: $fs"
  144.  
  145. echo " "
  146.  
  147. # cycle for each filesystem that needs to be done
  148. foreach filesystem ( ${fs} )
  149.     if (!(-e ${FLAGFILE}.${filesystem})) then
  150.         unset restart
  151.  
  152. #look up raw device name in /etc/fstab
  153.         if ($filesystem == "root") then
  154.             set DEV = `awk -F: '$2 ~ /\/$/ { print $1}'\
  155.                  /etc/fstab`
  156.         else
  157.             set DEV = `awk -F: '$2 ~ /'${filesystem}'$/\
  158.                  { print $1}' /etc/fstab`
  159.         endif
  160.  
  161. #do the dump
  162.         echo -n "Type 'yes' when the /${filesystem} tape is online: "
  163.         set junk=$<
  164.         while ((${junk} != "yes") && (${junk} != "y"))
  165.             echo -n "Type 'yes' when the /$filesystem tape is online:"
  166.             set junk=$<
  167.         end
  168.  
  169.         echo "Doing the dump...."
  170.         ${DUMP} ${lolevel}udf ${DEN} ${DUMPDEV} ${DEV} |& tee $TEMPFILE
  171.  
  172.         touch ${FLAGFILE}.${filesystem}
  173.  
  174.     else
  175.         echo "Apparently the ${filesystem} dump has been done."
  176.     endif
  177.  
  178. # do the dumptoc
  179.     if (!(-e ${FLAGFILE}.r${filesystem})) then
  180.  
  181.         echo -n "Doing the dumptoc..."
  182.         ${RESTORE} tf ${DUMPDEV} > ${DUMPDIR}/lev${level}.${filesystem}
  183.         touch ${FLAGFILE}.r${filesystem}
  184.         echo "Done"
  185.         if (-z ${DUMPDIR}/lev${level}.${filesystem}) then
  186.             echo "PANIC\!"
  187.             echo "${DUMPDIR}/lev${level}.${filesystem} is empty\!"
  188.         endif
  189.         echo -n "Level ${level} /${filesystem}       " >> ${DATEFILE}
  190.         echo -n `date` >> ${DATEFILE}
  191.         echo " by ${USER}" >> ${DATEFILE}
  192.     else
  193.         echo "And the dumptoc for ${filesystem} has been done also."
  194.     endif
  195. end
  196.  
  197. rm -f ${FLAGFILE}.*
  198.     
  199. goto clean
  200.  
  201. quit:
  202. echo ""
  203. echo "The dump has been killed.... I hope you know what you are doing\!"
  204. echo ""
  205.  
  206. clean:
  207. rm -f ${FLAGDIR}/${FNAME}*
  208. cd
  209.